MAC: Netzlaufwerk dauerhaft anmelden, aber nicht bei Neustart öffnen

[viggo]

Hallo, ich krieg grad nen Vogel..

Was muss man denn machen, damit ein Macbook ein Synology-Laufwerk, bzw. ein Synolgoy-Ordner zwar unter "Ordner" anzeigt, aber der Ordner nicht beim Neustart des Rechners geöffnet wird?

Damit der Ordner überhaupt nach dem Neustart unter "Orte" erscheint, muss ich ihn ja unter Systemeinstellungen/Anmeldeinformationen eintragen.
Dadurch wird der Ordner aber eben nicht nur unter "Orte" sichtbar, sondern auch beim Start geöffnet.

Kann jemand helfen?

Danke euch!

Servus, Markus

 

[luddi]

Hallo,

wenn du möchtest dass die Finder Fenster der verbundenen Freigaben nicht geöffnet werden dann kommst du wohl um ein Script oder zusätzliche Tools nicht herum.

Du könntest hier einmal nachlesen: https://www.synology-forum.de/threads/dauerhafte-verbindung-zur-synology-bei-mac.140353/

Ich habe das Script welches ich dort zur Verfügung gestellt habe etwas angepasst.

1. Man startet den Scripteditor von Apple und fügt folgendes ein.

set serv to "MEIN_SERVER_NAME._smb._tcp.local" -- Server hostname
set servIPv4 to "192.168.x.y" -- IPv4 Adresse des Servers (NAS) als Alternative zu server hostname
set sharesToMount to {"freigabe1", "freigabe2", "freigabe3"} -- Name der Freigabe welche verbunden werden soll
set connected to false
set maxTriesMount to 3 -- maximale Anzahl der Versuche für das Einhängen des(r) Volumes


-- Function to ping server and check availability
on checkServer(ServerIP)
    set maxTriesPing to 100 -- maximale Anzahl der Versuche für den Ping des Servers
    repeat with i from 1 to maxTriesPing
        try
            do shell script "ping -t 2 -c 1 " & ServerIP
            return true
        on error
            -- delay 2 -- wait 2 seconds before next try
        end try
    end repeat
end checkServer


-- Call the function to check server availability and start trying to mount volumes on success
if my checkServer(servIPv4) then
    repeat with vol in sharesToMount
        set success to false
        repeat with i from 1 to maxTriesMount
            try
                mount volume "smb://" & serv & "/" & vol
                set connected to true
                set success to true
                exit repeat
            on error
                delay 2 -- wait 2 seconds before next try
            end try
        end repeat
        if not success then
            display dialog "Fehler beim Verbinden mit \"" & vol & "\" nach " & maxTriesMount & " Versuchen." with icon caution buttons {"OK"}
        end if
    end repeat
else
    activate
    display dialog "Server \"" & serv & "\" ist momentan nicht erreichbar!" with icon stop giving up after 20
end if

2. In Zeile 1 den Hostnamen deines Servers angeben: "MEIN_SERVER_NAME" ersetzen
3. In Zeile 2 die IP-Adresse deines Server eintragen: "192.168.x.y." ersetzen
4. In Zeile 3 alle Freigaben eintragen die eingehängt werden sollen
5. Das Script speichern (z.B. unter dem Namen "Mount-NAS-Share.scpt"
6. Das Script über "Ablage -> Exportieren" und hierbei das Dateiformat "App" auswählen


7. Die exportierte App wie gewohnt in den Anmeldeobjekten einfügen

Viel Vergnügen damit

 

[synfor]

-- Function to ping server and check availability on checkServer(ServerIP)
on checkServer(ServerIP)

Müsste es dort nicht servIPv4 statt ServerIP heißen?

 

[luddi]

Nur wenn man es aus kosmetischer Sicht betrachtet könnte man es auch servIPv4 nennen.
Aber die Funktion kann auch verwendet werden wenn eine IPv6 Adresse übergeben wird. Somit ist der Variablenname ServerIP unabhängig des Typs gewählt worden.

Denn

on checkServer(ServerIP)

ist eine Funktionsdefinition und erwartet einen Parameter. Hier könnte man ja jeden beliebigen Namen verwenden denn es spielt keine Rolle wie die Variable heißt die hier übergeben wird. Solange der Parameter innerhalb der Funktion genau so verwendet wird spricht ja nichts dagegen.

Beim Aufruf der Funktion wird die Variable servIPv4 an die Funktion übergeben und innerhalb der Funktion mit dem Namen ServerIP weiter behandelt:

if my checkServer(servIPv4) then

Die Funktionsdefinition könnte auch so aussehen.

on checkServer(var)
...
...
      try
            do shell script "ping -t 2 -c 1 " & var
            return true

 

[nasinterested]

immer ein wenig schade, wenn sich Leute so viel Mühe geben und dann kein Feedback kommt. Noch besser: kein Feedback und an mehreren Stellen fragen...

https://www.macuser.de/threads/netz...melden-aber-nicht-bei-neustart-offnen.963841/