PC über die NAS Weboberfläche neustarten / herunterfahren

[freeuser616]

Hallo zusammen,

ich hab mal ne frage..

und zwar.... gibt es ein paket bzw. eine möglichkeit, womit ich über die nas weboberfläche meinen PC, welches sich im gleichen Netz wie die NAS befindet, neustarten bzw. herunterfahren kann?

über SSH ist das kein problem. jedoch benötige ich eine variante, mit der ich den shutdown befehl über die weboberfläche abgeben kann.


danke schon mal im voraus

 

[peterhoffmann]

Wenn du den anderen PC per SSH erreichen und runterfahren kannst, kannst du dich doch per SSH von der DS dort einloggen und ihn runterfahren. Das müsste sogar mittels Befehl über den Aufgabenplaner gehen.

 

[AndiHeitzer]

Ich habs bei mir so gelöst, dass ich auf dem Computer im Aufgabenplaner ein Script laufen lasse.
Dieses Script guckt nach, ob es eine Datei COMPUTERNAME.Reboot / COMPUTERNAME.ShutDown / COMPUTERNAME.LogOff auf einem gemeinsamen Ordner gibt.
Sofern eine entsprechende Datei vorhanden ist, dann startet der Computer die gewünschte Aktion.

Auf dem NAS gehe ich her und erstelle eine ensprechende Datei in der Filestation und schwups ... ich darf mich dann freuen

 

[freeuser616]

Wenn du den anderen PC per SSH erreichen und runterfahren kannst, kannst du dich doch per SSH von der DS dort einloggen und ihn runterfahren. Das müsste sogar mittels Befehl über den Aufgabenplaner gehen.

und die frage wäre jetzt, wie und wo auf dem web frontend kann ich die command line aufrufen um den shutdown befehl auszuführen.
von mir aus auch über den aufgabenplanner der DS, wenn mir jemand ne kurze step by step anleitung geben könnte..

 

[freeuser616]

Ich habs bei mir so gelöst, dass ich auf dem Computer im Aufgabenplaner ein Script laufen lasse.
Dieses Script guckt nach, ob es eine Datei COMPUTERNAME.Reboot / COMPUTERNAME.ShutDown / COMPUTERNAME.LogOff auf einem gemeinsamen Ordner gibt.
Sofern eine entsprechende Datei vorhanden ist, dann startet der Computer die gewünschte Aktion.

Auf dem NAS gehe ich her und erstelle eine ensprechende Datei in der Filestation und schwups ... ich darf mich dann freuen

hm... ganz schön pfiffig..
notfalls würde ich das glaube ich auch so machen... wie würde denn das passende script ausschauen?

 

[Fusion]

Wie machst du es denn über SSH?
Den Befehl kann man ja oft einfach 1:1 in den Aufgabenplaner reinklatschen.

 

[freeuser616]

Wie machst du es denn über SSH?
Den Befehl kann man ja oft einfach 1:1 in den Aufgabenplaner reinklatschen.

von außerhalb, bspw. über das handy mit dem befehl net rpc shutdown -r -f -t 15 -C "Rechner wird neu gestartet" -I IPADDRESS -U USERNAME%PASSWORD

aber wie gesagt, ich brauch die möglichkeit, außerhalb das ganze auch über das webfrontend zu machen.

 

[Kurt-oe1kyw]

hmmmmmm, ich frag mal ganz vorsichtig:
Warum klickst du im DSM nicht ganz einfach auf "Herunterfahren" und gut ist?



Wär halt für mich der einfachste Weg

OK, falscher Weg - ich hab gerade gesehen es soll DER PC (!) und nicht die DS heruntergefahren werden, sri.

 

[AndiHeitzer]

... wie würde denn das passende script ausschauen?

Auf dem PC im BATCH-File:

@ECHO OFF
REM ********************************************************************
REM * Script, um Computer zu steuern (reboot/logoff/shutdown)
REM * ------------------------------------------------------------------
REM * Aufruf durch - reboot_shut.bat
REM ********************************************************************


SETLOCAL enabledelayedexpansion
@ECHO OFF
CLS


TITLE reboot_shut.bat
ECHO reboot_shut.bat


REM ***** Variablen definieren
ECHO Variablen definieren
SET LOGFILE=%TEMP%\%COMPUTERNAME%_REBOOTLOG.TXT
SET ACTIONDIR=N-LOGON\ACTION
SET DATUM=!DATE:^ =0!
SET ZEIT=!TIME:^ =0!
SET ZEITPUNKT=[%DATUM% - %ZEIT%]


REM ***** Aktiven Server raussuchen
ECHO Aktiven Server raussuchen
SET SERVER=UNBEKANNT
PING DS916AH -n 1 -w 110
IF %ERRORLEVEL%==0 SET SERVER=DS916AH
PING DS215RH -n 1 -w 110
IF %ERRORLEVEL%==0 SET SERVER=DS215RH
IF %SERVER%==UNBEKANNT GOTO :ENDE


REM ***** Vorlagendatei erstellen
ECHO .>\\%SERVER%\%ACTIONDIR%\_%COMPUTERNAME%.logoff
ECHO .>\\%SERVER%\%ACTIONDIR%\_%COMPUTERNAME%.reboot
ECHO .>\\%SERVER%\%ACTIONDIR%\_%COMPUTERNAME%.shutdown
ECHO ######################################################################## >>%LOGFILE%
ECHO Aktion 'REBOOT' beginnt
ECHO %ZEITPUNKT% Aktion 'REBOOT' beginnt>>%LOGFILE%


REM ***** Bedingung suchen
IF EXIST \\%SERVER%\%ACTIONDIR%\%COMPUTERNAME%.logoff GOTO :ABMELDEN
IF EXIST \\%SERVER%\%ACTIONDIR%\%COMPUTERNAME%.reboot GOTO :DURCHSTARTEN
IF EXIST \\%SERVER%\%ACTIONDIR%\%COMPUTERNAME%.shutdown GOTO :HERUNTERFAHREN
ECHO Keine Aktion (logoff/reboot/shutdown) gefunden
ECHO Keine Aktion (logoff/reboot/shutdown) gefunden>>%LOGFILE%
GOTO :ENDE


:ABMELDEN
REM ***** Benutzer wird abgemeldet
DEL \\%SERVER%\%ACTIONDIR%\%COMPUTERNAME%.logoff /Q
ECHO LOGOFF wird abgearbeitet
ECHO LOGOFF wird abgearbeitet>>%LOGFILE%
LOGOFF
GOTO :ENDE


:DURCHSTARTEN
REM ***** Computer wird restartet
DEL \\%SERVER%\%ACTIONDIR%\%COMPUTERNAME%.reboot /Q
ECHO SHUTDOWN -F -R -T 15 wird abgearbeitet
ECHO SHUTDOWN -F -R -T 15 wird abgearbeitet>>%LOGFILE%
SHUTDOWN -F -R -T 15
GOTO :ENDE


:HERUNTERFAHREN
REM ***** Computer wird heruntergefahren
DEL \\%SERVER%\%ACTIONDIR%\%COMPUTERNAME%.shutdown /Q
ECHO SHUTDOWN -F -S -T 15 wird abgearbeitet
ECHO SHUTDOWN -F -S -T 15 wird abgearbeitet>>%LOGFILE%
SHUTDOWN -F -S -T 15
GOTO :ENDE


:ENDE


REM ***** Logfile schreiben
ECHO ------------------------------------------------------------------------ >>%LOGFILE%


SETLOCAL disabledelayedexpansion


EXIT

Unter DSM funzt das eigentlich genauso

Damit das auch Remote tut, also auf dem Smartphone, erstellt jeder PC (auch die DS) eine 'Vorlagedatei' => _COMPUTER.REBOOT usw.
So brauche ich per DS-FILE auf dem Handy nur den Unterstrich entfernen und muss nicht lange rumtippern ...

 

[Puppetmaster]

@Kurt: "PC über die NAS Weboberfläche neustarten / herunterfahren"

 

[AndiHeitzer]

hmmmmmm, ich frag mal ganz vorsichtig:
Warum klickst du im DSM nicht ganz einfach auf "Herunterfahren" und gut ist?

Weil er nicht die DS runterfahren möchte, sondern seinen PC
Und dies halt ohne den PC anfassen zu müssen ...


EDIT MEINT:
Puppetmaster war schneller ...

 

[Kurt-oe1kyw]

Joho siehe mein Beitrag #8, beim nochmaligen "drüberlesen" hab ich es dann auch gesehen